可以使用逐像素光照来得到更加平滑的高光效果。

Shader代码

Shader "Custom/Chapter6-SpecularPixelLevel" {
	Properties {
		//漫反射颜色
		_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
		//高光反射系数,用于控制材质的高光反射颜色
		_Specular ("Specular", Color) = (1, 1, 1, 1)
		//光泽度(反射度)，用于控制高光区域的大小,值越大，亮点越小
		_Gloss ("Gloss", Range(8.0, 256)) = 20
	}
	SubShader {
		Pass {
			//只有定义了正确的LightMode才能得到一些Unity的内置光照变量，例如_LightColor0
			Tags { "LightMode"="ForwardBase" }
			
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"
			#include "Lighting.cginc"
			
			fixed4 _Diffuse;
			fixed4 _Specular;
			float _Gloss;
			
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
			};
			
			struct v2f {
				float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
			};
			
			v2f vert(a2v v) {
				v2f o;
				//把顶点位置从模型空间转换到裁剪空间
				o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
				//把模型法线从模型空间转换到世界空间
				o.worldNormal = mul(v.normal, (float3x3)_World2Object);
				//把顶点坐标从模型空间转换到世界空间
				o.worldPos = mul(_Object2World, v.vertex).xyz;
				return o;
			}
			
			//高光反射光照模型——逐像素光照
			fixed4 frag(v2f i) : COLOR
			{
				//========================漫反射代码=========================
				//得到环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
				fixed3 worldNormal = normalize(i.worldNormal);
				//光源方向
				//这种获取方式只适合场景中只有一个平行光的情况
				fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
				//漫反射公式
				//_LightColor0: 光源的颜色和强度信息(注意,想要得到正确的值需要定义合适的LightMode标签)
				//_Diffuse: 材质的漫反射系数
				//saturate(x): 把x截取在[0,1]范围内，如果x是个矢量，那么会对它的每一个分量进行这样的操作。
				fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));
				//============================End============================
				
				//========================高光反射代码=========================
				//通过入射光矢量与模型法线计算出反射光矢量
				fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal));
				//计算视角方向
				//_WorldSpaceCameraPos: 世界空间中的摄像机位置
				//_Object2World: 模型空间到世界空间的转换矩阵
				//视角方向 = 摄像机位置 - 模型顶点在世界空间中的位置
				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
				//_LightColor0: 入射光线的颜色和强度
				//_Specular: 高光反射系数
				//_Gloss: 材质的光泽度(反光度),值越大，亮点越小。
				//reflectDir: 反射光方向
				//viewDir: 视角方向
				fixed3 specular = _LightColor0.rgb*_Specular.rgb*pow(saturate(dot(reflectDir, viewDir)), _Gloss);
				//============================End============================
				
				return fixed4(ambient + diffuse + specular, 1.0);
			}
			ENDCG
		}
	} 
	FallBack "Diffuse"
}

效果