基本的顶点照明计算完成以后，将进行纹理设置。在ShaderLab中用SetTexture命令来设置纹理。当使用片元程序时SetTexture命令无效，在这种情况下像素操作完全在片元程序中完成。

    纹理处理是在做旧式的合并效果。在一个通道中可以使用多个SetTexture命令——所有的纹理应用都在一个队列当中，就像绘制程序中的层一样。SetTexture命令必须放置在通道的末尾。

SetTexture命令如下:

SetTexture [ 纹理属性名 ] { 纹理块 }

   指派一个纹理，纹理名必须是纹理属性中定义的名字。如何应用纹理是在纹理块中设置的。在纹理块中执行3种命令，具体如下所列。

合并(combine)

常用的合并命令

combine 源1 * 源2	将源1和源2相乘。结果纹理将比输入纹理更暗
combine 源1 + 源2	将源1和源2相加。结果纹理将比输入纹理更明亮
combine 源1 - 源2	源1和源2相减
combine 源1 +- 源2	源1和源2加相，然后减去0.5
combine 源1 lerp (源2) 源3	使用源2的透明度(alpha)值在源3和源1之间进行插值，注意插值是反向的:当透明度值是1时使用源1,透明度为0时使用源3
combine 源1 * 源2 + 源3	源1和源2的透明度(alpha)相乘，然后加上源3
combine 源1 * 源2 +- 源3	源1和源2的透明度(alpha)相乘，然后和源3做有符号加法
combine 源1 * 源2 - 源3	源1和源2的透明度(alpha)相乘，然后和源3相减

说明

   上述的公式都均能通过关键字double或quad将最终颜色调高亮度2倍或4倍。所有的源属性，除了插值参数都可以使用符号“-”来使最终颜色反相。所有源属性能通过附加透明度(alpha)标签来表示只取用透明度通道。

所有源属性都可以是previous、constant、primary或texture中的一个:

源属性

previous	上一次使用SetTexture的结果
primary	来自光照计算的颜色或是当顶点绑定时的顶点颜色
texture	在SetTexture命令中指定的纹理的颜色
constant	常量颜色，从ConstantColor设置中得到

提示

   默认情况下primary颜色是漫反射颜色，环境光颜色和高光颜色(在光照计算中定义)的加和,如果将通道设置中的SeparateSpecular打开，高光色会在混合计算后被加入，而不是之前。这是内置顶点程序的默认操作。

默认情况下，混合公式被同时用于计算纹理的RGB通道和透明度。同时，也能指定只针对透明度进行计算，下面的代码片段对这种情况进行了说明:

//对RGB的颜色做乘然后对透明度相加

SetTexture [ _MainTex ] { combine previous * texture, previous + texture }

常量色(constantColor)

   可以使用ConstantColor定义在合并命令中能被使用的常量颜色，具体语法如下。

   constantColor <颜色>

矩阵(matrix)

   矩阵命令使用给定的矩阵对纹理坐标进行变换。具体语法如下。

   matrix [矩阵属性名]

   一些旧的显卡可能不支持一些纹理合并的模式，不同的显卡有不同数量的SetTexture阶段可用。编写着色器时应该要编写想要支持的显卡的独立SubShaders。支持像素着色器1.1的显卡(NVIDIA公司的GeForce3, ATI RADEON 8500及以上，英特尔9XXX)，支持所有合并模式，并至少有4个纹理阶段，表总结了硬件支持。

硬件支持

显卡	阶段数量	不支持的合并模式
NVIDIA GeForce 3/4Ti and up	4	在Windows平台的OpenGL中不支持 源1*源2-源3
NVIDIA TNT2, GeForce 256, GeForce 2, GeForce 4MX	2	在Windows平台的OpenGL中不支持 源1*源2-源3
ATI Radeon 9500 and up	4-8	8 in OpenGL, 4 in D3D9
ATI Radeon 8500-9250	4-6	8 in OpenGL, 4 in D3D9
ATI Radeon 7500	3
ATI Rage	2	源1*源2+源3 源1*源2+-源3 源1*源2-源3

下面的代码是一个使用了纹理合并的完整着色器:

Shader "Examples/Self-Illumination 3" {
	Properties {
		//定义颜色属性
		_IlluminCol ("Self-Illumination color (RGB)", Color) = (1,1,1,1)
		_Color ("Main Color", Color) = (1,1,1,0)
		_SpecColor ("Spec Color", Color) = (1,1,1,1)
		_Emission ("Emmisive Color", Color) = (0,0,0,0)
		_Shininess ("Shininess", Range (0.01, 1)) = 0.7 //定义浮点数范围属性
		_MainTex ("Base (RGB)", 2D) = "white" {} //定义2D纹理属性
	}
	SubShader {
		Pass {
			Material {
				Diffuse [_Color] //设置漫反射光颜色
				Ambient [_Color] //设置环境光颜色
				Shininess [_Shininess] //设置加亮时光泽度
				Specular [_SpecColor] //设置高光颜色
				Emission [_Emission] //设置自发光颜色
			}
			Lighting On //开启光照
			SetTexture [_MainTex] {
				constantColor [_IlluminCol] //定义颜色常量
				combine constant lerp(texture) previous //用纹理alpha混合顶点色和纯白色
			}
			SetTexture [_MainTex] { //混合纹理
				combine previous * texture
			}
		}
	}
}