鸟语天空

Bloom效果

作者：追风剑情 发布于：2016-12-24 20:36 分类：Shader

      Bloom特效是游戏中常见的一种屏幕效果。这种特效可以模拟真实摄像机的一种图像效果，它让画面中较亮的区域“扩散”到周围的区域中，造成一种朦胧的效果。

      Bloom的实现原理非常简单：我们首先根据一个阈值提取出图像中的较亮区域，把它们存储在一张渲染纹理中，再利用高斯模糊对这张渲染纹理进行模糊处理，模拟光线扩散的效果，最后再将其和原图像进行混合，得到最终的效果。

Shader代码

//Bloom模糊
Shader "Custom/Chapter12-Bloom" {
	Properties {
		_MainTex ("Base (RGB)", 2D) = "white" {}
		//高斯模糊后的较亮区域
		_Bloom ("Bloom (RGB)", 2D) = "black" {}
		//用于提取较亮区域使用的阈值
		_LuminanceThreshold ("Luminance Threshold", float) = 0.5
		//用于控制不同迭代之间高斯模糊的模糊区域范围
		_BlurSize ("Blur Size", float) = 1.0
	}
	SubShader {
		Tags { "RenderType"="Opaque" }
		LOD 200
		
		ZTest Always Cull Off ZWrite Off
		
		CGINCLUDE
		#include "UnityCG.cginc"
		
		sampler2D _MainTex;
		half4 _MainTex_TexelSize;
		sampler2D _Bloom;
		float _LuminanceThreshold;
		float _BlurSize;
		
		//以下定义提取较亮区域需要使用的顶点着色器和片元着色器
		
		struct v2f {
			float4 pos : SV_POSITION;
			half2 uv : TEXCOORD0;
		};
		
		v2f vertExtractBright(appdata_img v) {
			v2f o;
			o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
			o.uv = v.texcoord;
			
			return o;
		}
		
		fixed luminance(fixed4 color) {
			return 0.2125 * color.r + 0.7154 * color.g + 0.0721 * color.b;
		}
		
		fixed4 fragExtractBright(v2f i) : COLOR {
			fixed4 c = tex2D(_MainTex, i.uv);
			//采样得到的亮度值减去阈值，并把结果截取到0-1范围内。
			fixed val = clamp(luminance(c) - _LuminanceThreshold, 0.0, 1.0);
			//把该值和原像素值相乘，得到提取后的亮度区域
			return c * val;
		}
		
		//以下定义了混合亮部图像和原图像时使用的顶点着色器和片元着色器
		
		struct v2fBloom {
			float4 pos : SV_POSITION;
			half4 uv : TEXCOORD0;
		};
		
		v2fBloom vertBloom(appdata_img v) {
			v2fBloom o;
			o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
			//我们定义了两个纹理坐标，并存储在同一个类型为half4的变量uv中。
			//它的xy分量对应了_MainTex，即原图像的纹理坐标。而它的zw分量是_Bloom，
			//即模糊后的较亮区域的纹理坐标。
			o.uv.xy = v.texcoord;
			o.uv.zw = v.texcoord;
			
			//平台差异化处理
			#if UNITY_UV_STARTS_AT_TOP
			if (_MainTex_TexelSize.y < 0.0)
				o.uv.w = 1.0 - o.uv.w;
			#endif
			
			return o;
		}
		
		fixed4 fragBloom(v2fBloom i) : COLOR {
			//把两张纹理的采样结果相加混合。
			return tex2D(_MainTex, i.uv.xy) + tex2D(_Bloom, i.uv.zw);
		}
		ENDCG
		
		Pass {
			CGPROGRAM
			#pragma vertex vertExtractBright
			#pragma fragment fragExtractBright
			ENDCG
		}
		
		//直接引用前面高斯模糊定义的Pass
		//需要注意的是，由于Unity内部会把所有Pass的Name转换成大写字母表示，因此
		//在使用UsePass命令时我们必须使用大写形式的名字。
		UsePass "Custom/Chapter12-GaussianBlur/GAUSSIAN_BLUR_VERTICAL"
		
		UsePass "Custom/Chapter12-GaussianBlur/GAUSSIAN_BLUR_HORIZONTAL"
		
		Pass {
			CGPROGRAM
			#pragma vertex vertBloom
			#pragma fragment fragBloom
			ENDCG
		}
	} 
	FallBack Off
}

需要挂在摄像机上的脚本

using UnityEngine;
using System.Collections;

public class Bloom : PostEffectsBase {

	public Shader bloomShader;
	private Material bloomMaterial = null;
	public Material material {
		get {
			bloomMaterial = CheckShaderAndCreateMaterial(bloomShader, bloomMaterial);
			return bloomMaterial;
		}
	}
	//以下三个变量对应高斯模糊中的定义
	[Range(0, 4)]
	public int iterations = 3;
	[Range(0.2f, 3.0f)]
	public float blurSpread = 0.6f;
	[Range(1, 8)]
	public int downSample = 2;
	//尽管在绝大多数情况下，图像的亮度值不会超过1。但如果我们开启了HDR，硬件会允许我
	//们把颜色值存储在一个更高精度范围的缓冲中，此时像素的高度值可能会超过1。因此，在这里
	//我们把luminanceThreshold的值规定在[0, 4]范围内。
	[Range(0.0f, 4.0f)]
	public float luminanceThreshold = 0.6f;

	void OnRenderImage (RenderTexture src, RenderTexture dest) {
		if (material != null) {
			material.SetFloat("_LuminanceThreshold", luminanceThreshold);

			int rtW = src.width/downSample;
			int rtH = src.height/downSample;

			RenderTexture buffer0 = RenderTexture.GetTemporary(rtW, rtH, 0);
			buffer0.filterMode = FilterMode.Bilinear;
                        //提取图像中较亮的区域
			Graphics.Blit(src, buffer0, material, 0);

			for(int i=0; i<iterations; i++) {
				material.SetFloat("_BlurSize", 1.0f + i * blurSpread);

				RenderTexture buffer1 = RenderTexture.GetTemporary(rtW, rtH, 0);
				//对垂直方向进行模糊处理
				Graphics.Blit(buffer0, buffer1, material, 1);

				RenderTexture.ReleaseTemporary(buffer0);
				buffer0 = buffer1;
				buffer1 = RenderTexture.GetTemporary(rtW, rtH, 0);

				//对水平方向进行模糊处理
				Graphics.Blit(buffer0, buffer1, material, 2);

				RenderTexture.ReleaseTemporary(buffer0);
				buffer0 = buffer1;
			}

			material.SetTexture("_Bloom", buffer0);
			Graphics.Blit(src, dest, material, 3);

			RenderTexture.ReleaseTemporary(buffer0);
		} else {
			Graphics.Blit(src, dest);
		}
	}
}

效果截图

标签: Shader